nix/flake.nix at main · willforman/nix · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
{
  description = "My nix config";

  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";

    home-manager.url = "github:nix-community/home-manager";
    home-manager.inputs.nixpkgs.follows = "nixpkgs";

    darwin.url = "github:lnl7/nix-darwin/master";
    darwin.inputs.nixpkgs.follows = "nixpkgs";

    determinate.url = "https://flakehub.com/f/DeterminateSystems/determinate/*";

    agenix.url = "github:ryantm/agenix";
    agenix.inputs.nixpkgs.follows = "nixpkgs";

    mac-app-util.url = "github:hraban/mac-app-util";
    # mac-app-util.inputs.nixpkgs.follows = "nixpkgs";

    claude-code.url = "github:sadjow/claude-code-nix";
  };

  outputs = {
    self,
    nixpkgs,
    home-manager,
    darwin,
    agenix,
    mac-app-util,
    claude-code,
    determinate,
    ...
    } @ inputs: let
      inherit (self) outputs;

      systems = [
        "x86_64-linux"
        "aarch64-darwin"
      ];

      forAllSystems = nixpkgs.lib.genAttrs systems;
    in
    {

      packages = forAllSystems (system: import ./pkgs nixpkgs.legacyPackages.${system});

    overlays = import ./overlays { inherit inputs; };

    nixosConfigurations =
      let mkHost = hostname: nixpkgs.lib.nixosSystem {
        specialArgs = { inherit inputs outputs; };
        modules = [
          ./os/lib/common.nix
          ./os/nixos/common.nix
          ./os/nixos/${hostname}
          determinate.nixosModules.default
        ];
      };
      in {
        dev = mkHost "dev";
        remote-dev = mkHost "remote-dev";
        desktop = mkHost "desktop";
      };

    homeConfigurations =
      let mkHost = { system, hostname, username, homeDirectory }:
        home-manager.lib.homeManagerConfiguration {
          pkgs = nixpkgs.legacyPackages.${system};
          extraSpecialArgs = { inherit inputs outputs; };
          modules = [
            ./home-manager/lib/common.nix
            ./home-manager/${hostname}
            {
              home = { inherit username homeDirectory; };
            }
            agenix.homeManagerModules.default
            mac-app-util.homeManagerModules.default
          ];
        };
      in {
        dev = mkHost {
          system = "x86_64-linux";
          hostname = "dev";
          username = "will";
          homeDirectory = "/home/will";
        };
        remote-dev = mkHost {
          system = "aarch64-linux";
          hostname = "remote-dev";
          username = "will";
          homeDirectory = "/home/will";
        };
        mbp = mkHost {
          system = "aarch64-darwin";
          hostname = "mbp";
          username = "will";
          homeDirectory = "/Users/will";
        };
        desktop = mkHost {
          system = "x86_64-linux";
          hostname = "desktop";
          username = "will";
          homeDirectory = "/home/will";
        };
        work = mkHost {
          system = "aarch64-darwin";
          hostname = "work";
          username = "wforman";
          homeDirectory = "/Users/wforman";
        };
      };

    darwinConfigurations =
      let mkHost = hostname: darwin.lib.darwinSystem {
        system = "aarch64-darwin";
        specialArgs = { inherit inputs outputs; };
        modules = [
          mac-app-util.darwinModules.default
          ./os/lib/common.nix
          ./os/darwin/common.nix
          ./os/darwin/${hostname}
        ];
      };
      in {
        mbp = mkHost "mbp";
        work = mkHost "work";
      };
  };
}