lib/flake.nix at master · radrootslabs/lib · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
{
  description = "Radroots Core Libraries";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-25.11";
    flake-parts.url = "github:hercules-ci/flake-parts";
    crane.url = "github:ipetkov/crane";
    rust-overlay = {
      url = "github:oxalica/rust-overlay";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    treefmt-nix = {
      url = "github:numtide/treefmt-nix";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };

  outputs =
    inputs@{
      self,
      flake-parts,
      ...
    }:
    flake-parts.lib.mkFlake { inherit inputs; } {
      imports = [ inputs.treefmt-nix.flakeModule ];
      systems = import ./build/nix/service/systems.nix;

      flake.nixosModules.default =
        (import ./build/nix/service/nixos-module.nix { lib = inputs.nixpkgs.lib; })
          {
            serviceName = "fixture_service";
            binaryName = "fixture-service";
            packageFor = pkgs: self.packages.${pkgs.stdenv.hostPlatform.system}.default;
            commandForInstance = _: [ "--help" ];
          };

      perSystem =
        {
          config,
          lib,
          system,
          ...
        }:
        let
          pkgs = import inputs.nixpkgs {
            inherit system;
            overlays = [ inputs.rust-overlay.overlays.default ];
          };
          service = import ./build/nix/service {
            crane = inputs.crane;
            inherit lib pkgs;
          };
          toolchains = {
            stable = service.mkToolchain {
              rustToolchainFile = ./rust-toolchain.toml;
            };
            coverage = service.mkToolchain {
              rustToolchainFile = ./rust-toolchain-coverage.toml;
            };
          };
          common = import ./build/nix/common.nix {
            crane = inputs.crane;
            inherit lib pkgs toolchains;
          };
          serviceFixture = import ./build/nix/service/fixture.nix {
            inherit lib pkgs service;
            nixosSystem = inputs.nixpkgs.lib.nixosSystem;
            toolchain = toolchains.stable;
          };
        in
        {
          treefmt = import ./treefmt.nix;

          apps =
            (import ./build/nix/apps.nix {
              inherit
                common
                config
                lib
                pkgs
                toolchains
                ;
            })
            // serviceFixture.outputs.apps;

          checks = lib.filterAttrs (_: value: value != null) (
            (import ./build/nix/checks.nix {
              inherit common pkgs;
            })
            // serviceFixture.outputs.checks
          );

          devShells =
            (import ./build/nix/devshells.nix {
              inherit common pkgs toolchains;
            })
            // {
              service-fixture = serviceFixture.outputs.devShells.default;
            };

          packages = serviceFixture.outputs.packages // {
            xtask = common.xtaskPackage;
          };
        };
    };
}