opencadc.gradle

configurations {
    checkstyleDep
    intTestImplementation.extendsFrom testImplementation

    runtimeOnly.exclude module: 'slf4j-reload4j'
    runtimeOnly.exclude module: 'reload4j'
}

dependencies {
    testImplementation 'com.puppycrawl.tools:checkstyle:10.12.5'
    checkstyleDep 'org.opencadc:cadc-quality:[1.1,1.2)'
}

checkstyle {
    ignoreFailures = false
    config = resources.text.fromArchiveEntry(configurations.checkstyleDep, 'cadc_checkstyle.xml')
    toolVersion = '10.12.5'
    sourceSets = []
}

// enable additional warnings
tasks.withType(JavaCompile) {
    options.compilerArgs << "-Xlint:deprecation" << "-Xlint:unchecked"
}

sourceSets {
    intTest {
        java {
            compileClasspath += main.output + test.output
            runtimeClasspath += compileClasspath
        }
        resources.srcDirs += file('src/intTest/resources')
        resources.srcDirs += new File(System.getenv('A') + '/test-certificates/')
    }
}

// Temporary work around for issue https://github.com/gradle/gradle/issues/881 - 
// gradle not displaying fail build status when warnings reported -->
tasks.withType(Checkstyle).each { checkstyleTask ->
    checkstyleTask.doLast {
        reports.all { report ->
            def outputFile = report.outputLocation.get().asFile
            if (outputFile.exists() && outputFile.text.contains("<error ")) {
                throw new GradleException("There were checkstyle warnings! For more info check $outputFile")
            }
        }
    }
}

tasks.withType(Test).configureEach {
    // separate report destinations for each test task
    reports.html.outputLocation = layout.buildDirectory.dir("reports/tests/${name}")
    
    // assign all Java system properties from the command line to the tests
    systemProperties System.properties
    
    testLogging {
        events "PASSED", "FAILED", "SKIPPED"
    }
}

tasks.register('intTest', Test) {
    // Set the configuration context
    testClassesDirs = sourceSets.intTest.output.classesDirs
    classpath = sourceSets.intTest.runtimeClasspath
    
    // Run the tests always
    outputs.upToDateWhen { false }
}

pluginManager.withPlugin('maven-publish') {
  // configure maven-publish to support publishToMavenLocal
    publishing {
        publications {
            thisLibrary(MavenPublication) {
                from components.java
            }
        }
    }
}

// backwards compat usage
tasks.register('install') {
    dependsOn(tasks.named('publishToMavenLocal'))
}