Possible problem with HIDDEN methods overriding EXPORTED methods

[raphaelgz]

If a derived class overrides an EXPORTED method as HIDDEN the base class is not allowed to call that method anymore. Is this behavior expected?

The only information I could find that is possibly related to this is the commit 7463296 (search by HB_VIRTUAL_HIDDEN in that commit) were it appears to want to prevent a HIDDEN method from a base class from becoming EXPORTED or overridden in a derived class.

You can reproduce this behavior with the code below.

#include "hbclass.ch"

CLASS Base
EXPORTED:
    METHOD callPrint()
    METHOD print()
ENDCLASS

METHOD callPrint() CLASS Base
RETURN ::print()

METHOD print() CLASS Base
    ? "From Base"
RETURN Self

CLASS Derived INHERIT Base
HIDDEN:  // if you change this to EXPORTED or even PROTECTED this code works as expected
    METHOD print()
ENDCLASS

METHOD print() CLASS Derived
    ? "From Derived"
RETURN Self

PROCEDURE Main()

    LOCAL o
    
    o := Derived():New()
 
    o:print()       // Fails (expected)
    o:Super:print() // works (expected, prints "From Base")
    o:callPrint()   // Fails (not expected, should it print "From Derived"??)

RETURN

[alcz]

You can change callPrint like this to make it call to Base:

METHOD callPrint() CLASS Base
RETURN ::Base:print()

otherwise the methods call back to self which is an inherited instance - simplest explanation that can be provided.

Not sure what your real code looks like. There is albo -DHB_VIRTUAL_HIDDEN Harbour build flag in the commit message you've linked.

[raphaelgz]

Thank you for your response.

I understand that changing callPrint that way would stop the error but the intention here is to the code to work and print "From Derived". Also, the -DHB_VIRTUAL_HIDDEN does not change the behavior in this case, I mentioned it in the first message because it was the only information that I could find that could be related to this.

My main question is if this behavior is intended or not because:

1. The base class is allowed to call the method of the derived class if it is overridden as PROTECTED
2. The base class is not allowed to call the method of the derived class if it is overridden as HIDDEN
3. The tests/clsnv.prg file fails with the same error if Habour is compiled with HB_VIRTUAL_HIDDEN defined

From my perspective, the expected behavior would be one of the following:

• The base class is allowed to call an overridden method independent of the scope it has in the subclass, like it happens in C++
  • So the code in the first message works and prints "From Derived"
• The class can't be created if it changes the scope of the method, similar to Java
  • So the code in the first message fails inside the call to Derived() before the method New() is executed
• This error also happens if the overridden method is PROTECTED

Note: I don't have access to tools such as Class(y) or Xbase++, so I can't test whether this behavior is required for compatibility or if it's unintended.