feat: file repository (wraft#160)

* feat: implement integration management system
- Refactor vault utility to CloakVault for encryption.
- Introduce EncryptedMapType for storing encrypted map data.
- Add Integration and IntegrationConfig modules for managing external service integrations.
- Implement API endpoints for integration management, including listing, creating, enabling, and disabling integrations.
- Create views and controllers for integration configuration and management.
- Add migration for integrations table and update permissions for integration actions.

---------

Co-authored-by: Salsabeel <[email protected]>
Co-authored-by: Faheem vc <[email protected]>

Author: 3 people

config/config.exs

@@ -70,15 +70,30 @@ config :wraft_doc, :phoenix_swagger,
 # Cron jobs Overview https://github.com/sorentwo/oban#periodic-jobs
 config :wraft_doc, Oban,
   repo: WraftDoc.Repo,
-  queues: [default: 10, events: 50, media: 20, mailer: 20, scheduled: 10, webhooks: 15],
+  queues: [
+    default: 10,
+    events: 50,
+    media: 20,
+    mailer: 20,
+    scheduled: 10,
+    webhooks: 15,
+    cloud_provider: 15,
+    integrations: 15,
+    repository: 15
+  ],
   plugins: [
     Oban.Plugins.Pruner,
     {Oban.Plugins.Lifeline, rescue_after: :timer.minutes(5)},
     {Oban.Plugins.Cron,
      crontab: [
        #  {"0 0 * * MON", WraftDoc.Workers.ScheduledWorker,
        #   queue: :scheduled, tags: ["unused_assets"]},
+       {"0 3 * * *", WraftDoc.Workers.RepositoryWorker,
+        queue: :repository,
+        tags: ["repository_size_update"],
+        args: %{"action" => "update_repo_size"}},
        {"0 0 * * *", WraftDoc.Workers.ReminderWorker, queue: :scheduled, tags: ["reminders"]},
+       {"*/5 * * * *", WraftDoc.Workers.TokenRefreshWorker},
        {"@weekly", WraftDoc.Workers.ScheduledWorker,
         queue: :scheduled,
         tags: ["hard_delete_organisation_records"],
@@ -90,7 +105,8 @@ config :wraft_doc, Oban,
 
 # File Upload config
 config :waffle,
-  storage: Waffle.Storage.S3
+  storage: Waffle.Storage.S3,
+  version_timeout: 30_000
 
 config :ex_aws,
   json_codec: Jason,

lib/wraft_doc/application.ex

@@ -31,7 +31,9 @@ defmodule WraftDoc.Application do
       #   restart: :permanent
       # )
       WraftDoc.Schedulers.RefreshDashboardStats,
-      WraftDoc.Utils.Vault
+      WraftDoc.Utils.CloakVault,
+      {Registry, keys: :unique, name: WraftDoc.TokenRegistry},
+      {DynamicSupervisor, strategy: :one_for_one, name: WraftDoc.TokenSupervisor}
     ]
 
     # See https://hexdocs.pm/elixir/Supervisor.html

lib/wraft_doc/client/minio.ex

@@ -175,5 +175,75 @@ defmodule WraftDoc.Client.Minio do
     end
   end
 
+  @doc """
+  Check if a prefix exists in MinIO.
+  """
+  @spec prefix_exists?(String.t()) :: boolean()
+  def prefix_exists?(prefix) do
+    bucket()
+    |> S3.list_objects(prefix: prefix, max_keys: 1)
+    |> @ex_aws_module.request()
+    |> case do
+      {:ok, %{body: %{contents: []}}} -> false
+      {:ok, %{body: %{contents: _}}} -> true
+      _ -> false
+    end
+  end
+
+  @doc """
+  Renames a single file in MinIO (copy + delete).
+  Returns {:ok, new_path} on success.
+  """
+  @spec rename_file(String.t(), String.t()) :: ex_aws_response()
+  def rename_file(old_path, new_path) do
+    with {:ok, _} <- copy_files(new_path, old_path),
+         {:ok, _} <- delete_file(old_path) do
+      {:ok, new_path}
+    else
+      {:error, reason} -> {:error, reason}
+    end
+  end
+
+  @doc """
+  Renames a folder (prefix) and all files under it.
+  - Copies all objects from old_prefix -> new_prefix.
+  - Deletes the old ones after successful copy.
+
+  Example:
+      rename_folder("organisations/123/old/", "organisations/123/new/")
+  """
+  @spec rename_folder(String.t(), String.t()) :: :ok | {:error, any()}
+  def rename_folder(old_prefix, new_prefix) do
+    old_prefix = String.trim_trailing(old_prefix, "/") <> "/"
+    new_prefix = String.trim_trailing(new_prefix, "/") <> "/"
+
+    if prefix_exists?(old_prefix) do
+      bucket()
+      |> S3.list_objects_v2(prefix: old_prefix)
+      |> @ex_aws_module.stream!()
+      |> Task.async_stream(
+        fn %{key: old_key} ->
+          new_key = String.replace_prefix(old_key, old_prefix, new_prefix)
+
+          with {:ok, _} <- copy_files(new_key, old_key),
+               {:ok, _} <- delete_files(old_key) do
+            {:ok, new_key}
+          else
+            {:error, reason} ->
+              Logger.error("Failed to rename #{old_key}: #{inspect(reason)}")
+              {:error, reason}
+          end
+        end,
+        max_concurrency: 5,
+        timeout: :infinity
+      )
+      |> Enum.reduce_while(:ok, fn
+        {:ok, {:ok, _}}, acc -> {:cont, acc}
+        {:ok, {:error, reason}}, _ -> {:halt, {:error, reason}}
+        {:exit, reason}, _ -> {:halt, {:error, reason}}
+      end)
+    end
+  end
+
   defp bucket, do: System.get_env("MINIO_BUCKET")
 end