json/build.gradle at dev · MontiCore/json · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
// (c) https://github.com/MontiCore/monticore

/* ============================================================ */
/* ========================= Plugins ========================== */
/* ============================================================ */

plugins {
    id 'java'
    id "de.monticore.generator" version "$mc_version"
    id 'maven-publish'
    id "com.gradleup.shadow" version "$shadow_plugin_version"
    id "io.github.themrmilchmann.ecj" version "0.2.0"
}

/* ============================================================ */
/* ========================= Project ========================== */
/* ============================================================ */

group = 'de.monticore.lang'
description = 'json'

/* ============================================================ */
/* ======================= Configuration ====================== */
/* ============================================================ */

layout.buildDirectory = layout.projectDirectory.dir("target")

ecj {
    compilerVersion = "3.44.0"
}

java {
    toolchain {
        languageVersion = JavaLanguageVersion.of(21)
    }
}

test {
    useJUnitPlatform()
}

/* ============================================================ */
/* ======================= Dependencies ======================= */
/* ============================================================ */

repositories {
    if(("true").equals(getProperty('useLocalRepo'))){
        mavenLocal()
    }
    mavenCentral()
    maven {
        credentials.username = mavenUser
        credentials.password = mavenPassword
        url = repo
    }
}

dependencies {
    grammar ("de.monticore:monticore-grammar:$mc_version")
    implementation "org.assertj:assertj-core:$assertj_version"
    implementation "commons-cli:commons-cli:$commons_cli_version"
    implementation "org.apache.commons:commons-lang3:$commons_lang_version"
    implementation "net.sourceforge.plantuml:plantuml:$plantuml_version"


    testImplementation "org.junit.jupiter:junit-jupiter-api:$junit_version"
    testImplementation "org.junit.jupiter:junit-jupiter-params:$junit_version"
    testRuntimeOnly "org.junit.jupiter:junit-jupiter-engine:$junit_version"
    testRuntimeOnly "org.junit.platform:junit-platform-launcher:$junit_version"

}

/* ============================================================ */
/* ========================== Tasks =========================== */
/* ============================================================ */

tasks.withType(Copy).configureEach { duplicatesStrategy = DuplicatesStrategy.EXCLUDE }

tasks.withType(JavaCompile).configureEach {
  options.fork = true
  options.encoding = "UTF-8"
  options.deprecation = false
  options.warnings = false
  options.headerOutputDirectory.convention(null)
}

// build sources jar in addition
tasks.register('sourcesJar', Jar) {
    from sourceSets.main.allJava
    archiveClassifier = "sources"
}

sourcesJar.dependsOn project.collect { it.tasks.withType(MCTask)}

// build javadoc jar in addition
task javadocJar(type: Jar) {
    from javadoc
    archiveClassifier = "javadoc"
}

// generated java doc contains errors, disable for now
javadoc.failOnError = false

// all in one tool-jar
shadowJar {
    manifest {
        attributes "Main-Class": "de.monticore.lang.json.JSONTool"
    }
    archiveFileName = "MC${archiveBaseName.get()}.${archiveExtension.get()}"
    archiveClassifier = "mc-tool"
    minimize {
        exclude(dependency('org.freemarker:freemarker:.*'))
    }
}

jar.dependsOn shadowJar

/* ============================================================ */
/* ======================= Publishing ========================= */
/* ============================================================ */

publishing {
    // configure what artifacts to publish
    publications {
        mavenJava(MavenPublication) {
            artifactId = "$project.name"
            from components.java
            artifact sourcesJar
            artifact javadocJar
          //  artifact shadowJar
        }
    }
    repositories.maven {
        credentials.username = mavenUser
        credentials.password = mavenPassword
        def releasesRepoUrl = "https://nexus.se.rwth-aachen.de/content/repositories/monticore-releases/"
        def snapshotsRepoUrl = "https://nexus.se.rwth-aachen.de/content/repositories/monticore-snapshots/"
        url = version.endsWith("SNAPSHOT") ? snapshotsRepoUrl : releasesRepoUrl
    }
}

task buildAll(type: GradleBuild) {
  tasks = [ 'build' ]
}

defaultTasks 'build'