Unexpected SharedMemoryDataRace-RaceOnLoadStoreVsAtomic

[loryruta]

Environment:

• OS: Ubuntu 24.04
• GPU and driver version: RTX 3090 , Driver: 595.84
• SDK or header version if building from repo: 1.4.350
• Options enabled (synchronization, best practices, etc.):

Describe the Issue

Shader:

groupshared uint s_min[3];
groupshared uint s_max[3];

[ForceInline]
uint float_to_sortable_uint(float val) {
    uint temp = asuint(val);
    uint mask = uint(-int(temp >> 31)) | 0x80000000;
    return temp ^ mask;
}

[ForceInline]
float sortable_uint_to_float(uint val) {
    uint mask = ((val >> 31) - 1) | 0x80000000;
    return asfloat(val ^ mask);
}

[shader("compute")]
[numthreads(256, 1, 1)]
void compute_float3_minmax(float *points, uniform uint num_points,
                           uniform uint start_point_idx, uint *out_minmax,
                           uint gid: SV_DispatchThreadID,
                           uint tid: SV_GroupThreadID) {
    const uint global_idx = start_point_idx + gid;
    if (global_idx >= num_points)
        return;

    if (tid < 3) {
        s_min[tid] = 0xFFFFFFFFu;
        s_max[tid] = 0u;
    }

    GroupMemoryBarrierWithGroupSync();

    for (int d = 0; d < 3; ++d) {
        uint val = float_to_sortable_uint(points[global_idx * 3 + d]);
        // Wave min/max
        uint wave_min = WaveActiveMin(val);
        uint wave_max = WaveActiveMax(val);
        // Atomic min/max on shared memory
        if (WaveIsFirstLane()) {
            InterlockedMin(s_min[d], wave_min);
            InterlockedMax(s_max[d], wave_max);
        }
        GroupMemoryBarrierWithGroupSync();
        // Atomic min/max on global memory
        if (tid == 0) {
            InterlockedMin(out_minmax[d], s_min[d]);
            InterlockedMax(out_minmax[3 + d], s_max[d]);
        }
    }
}

Throws a validation error:

Validation Error: [ SharedMemoryDataRace-RaceOnLoadStoreVsAtomic ] | MessageID = 0x7600531a
vkCmdDispatch(): A data race was detected on the shared memory variable "s_max" in local invocation index 0 while performing a load or store operation. (Likely against unknown invocation)
The other access in this race was at:
Shader validation error occurred at gpu/seed_morton_sort.slang:53:13

53:             InterlockedMax(s_max[d], wave_max);
                ^
Stage = Compute.  Global invocation ID (x, y, z) = (0, 0, 0)
Command buffer (0xc0)
        Compute Dispatch Index 0
Shader Module (gpu/seed_morton_sort.spv)(0x55cc943a3cd0) (internal ID 22)
Shader validation error occurred at gpu/seed_morton_sort.slang:59:13

59:             InterlockedMax(out_minmax[3 + d], s_max[d]);
                ^
Objects: 3
    [0] VkQueue 0x55cc90229b30
    [1] VkCommandBuffer 0x55cc906dcbb0[stream_0]
    [2] VkPipeline 0x55cc93ba3ea0[compute_float3_minmax]

2026-07-30 12:56:04.566 [Error] (Vulkan) vkCmdDispatch(): A data race was detected on the shared memory variable "s_max" in local invocation index 0 while performing a load or store operation. (Likely against unknown invocation)
The other access in this race was at:
Shader validation error occurred at gpu/seed_morton_sort.slang:53:13

53:             InterlockedMax(s_max[d], wave_max);
                ^
Stage = Compute.  Global invocation ID (x, y, z) = (0, 0, 0)
Command buffer (0xc0)
        Compute Dispatch Index 0
Shader Module (gpu/seed_morton_sort.spv)(0x55cc943a3cd0) (internal ID 22)
Shader validation error occurred at gpu/seed_morton_sort.slang:59:13

59:             InterlockedMax(out_minmax[3 + d], s_max[d]);
                ^

But I can't see any data-race there. Could anyone explain? Is this validation error correct?

Expected behavior

No validation error...

Valid Usage ID

Additional context

[loryruta]

Likely due to the early return:

    if (global_idx >= num_points)
        return;

And subsequent barrier:

    GroupMemoryBarrierWithGroupSync();

Error is misleading though...

[jeffbolznv]

Does the failure go away if you avoid UB on the barriers?

[loryruta]

Yes @jeffbolznv

[jeffbolznv]

OK. This pass relies on barriers working correctly, and nonuniform control flow can cause UB where they won't synchronize. So I think that explains what's happening. I agree it's a misleading error message, it would be better if GPUAV could detect nonuniform control flow. But that is probably very difficult in general.

[jeffbolznv]

Thinking about this more, it's probably possible to validate barriers in a way that's similar to how the data race pass works. Store some small amount of info per thread and reset it after each barrier. I'll think about this and discuss with Spencer.

[spencer-lunarg]

Going to mark as a "would be cool to have one day" feature to better enhance this check.

As long as what was caught was a "real issue" (the early return causing non-uniform control flow) I am at least less concerned... this check, while useful, is really hard to provide a good error message for the reasons Jeff pointed out