build.gradle

plugins {
    id 'groovy'
    id 'java-gradle-plugin'
    id 'maven-publish'
}

group = 'dev.splitdeploy'
// In CI a release tag like v0.2.0 overrides this; keep it as the next
// planned version for local/composite-build use.
def refName = System.getenv('GITHUB_REF_NAME')
version = (refName ==~ /v\d.*/) ? refName.substring(1) : '0.2.6'

repositories {
    mavenCentral()
}

dependencies {
    testImplementation gradleTestKit()
    testImplementation 'org.junit.jupiter:junit-jupiter:5.11.4'
    testRuntimeOnly 'org.junit.platform:junit-platform-launcher:1.11.4'
}

tasks.withType(Test).configureEach {
    useJUnitPlatform()
    systemProperty 'splitDeployBuildVersion', version.toString()
}

// `publishAllPublicationsToStagingRepository` lays out a Maven repo in
// build/staging-repo; CI appends it to the gh-pages branch, which GitHub
// Pages serves at https://repo.cyclezlab.com.
publishing {
    repositories {
        maven {
            name = 'staging'
            url = layout.buildDirectory.dir('staging-repo')
        }
    }
}

gradlePlugin {
    website = 'https://github.com/CycleZLab/ftc-split-deploy'
    vcsUrl = 'https://github.com/CycleZLab/ftc-split-deploy'
    plugins {
        splitDeploy {
            id = 'ftc.splitdeploy'
            implementationClass = 'dev.splitdeploy.SplitDeploySettingsPlugin'
            displayName = 'FTC Split Deploy'
            description = 'Fast TeamCode iteration for FTC: packages TeamCode as a split APK and partially installs only that split (a few hundred KB) instead of reinstalling the whole Robot Controller app. Uses only official Android mechanisms (package-manager split sessions) — no custom classloaders.'
        }
    }
}