build.gradle

buildscript {
    ext {
        buildToolsVersion = "36.0.0"
        minSdkVersion = 25
        compileSdkVersion = 36
        targetSdkVersion = 36
        ndkVersion = "27.1.12297006"
        kotlinVersion = "2.1.20"
    }
    repositories {
        google()
        mavenCentral()
    }
    // RNRepo plugin classpath for CI builds (plugin applied in app/build.gradle).
    // To disable RNRepo support, set DISABLE_RNREPO environment variable to ANY value.
    def rnrepoClasspath = {
        def rnrepoDir = new File(
            providers.exec {
                workingDir(rootDir)
                commandLine("node", "--print", "require.resolve('@rnrepo/build-tools/package.json')")
            }.standardOutput.asText.get().trim()
        ).getParentFile().absolutePath
        return fileTree(dir: "${rnrepoDir}/gradle-plugin/build/libs", include: ["prebuilds-plugin.jar"])
    }
    dependencies {
        classpath("com.android.tools.build:gradle")
        classpath("com.facebook.react:react-native-gradle-plugin")
        classpath("org.jetbrains.kotlin:kotlin-gradle-plugin")
        classpath rnrepoClasspath()
    }
}

// Detox repository for `com.wix:detox` dependency specified
// in app build.gradle. This most likely does not have to be
// specified for each project but AFAIK it does not create any conflicts.
// See: https://github.com/wix/Detox/issues/3973#issuecomment-1459895555
// TODO: Find out which project should have it added.
allprojects {
    repositories {
        maven {
            url("$rootDir/../node_modules/detox/Detox-android")
        }
    }
}

apply plugin: "com.facebook.react.rootproject"

// Custom configuration. This is done in order to simplify process
// of upgrading the wrapper, eliminating necessity to manually specify CLI options
// to ensure that we use distribution of type `ALL`.
tasks.named("wrapper") {
    it.distributionType = Wrapper.DistributionType.ALL
}