nvme-cli/libnvme/src/nvme/meson.build at c738d415af2d154ba58f387d59766bd28de39c6d · martin-belanger/nvme-cli · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
# SPDX-License-Identifier: LGPL-2.1-or-later
#
# This file is part of libnvme.
# Copyright (c) 2025, Dell Technologies Inc. or its subsidiaries.
#
# Authors: Martin Belanger <[email protected]>
#
# Run generate-accessors to generate the setter/getter functions.

generated_h = 'accessors.h'
generated_c = 'accessors.c'
generated_ld = 'accessors.ld'

# List of header files to parse for structs
headers_to_scan = [
    '../nvme/private.h',
]

# Build the code generator tool
generate_accessors = executable(
    'generate-accessors',
    'generate-accessors.c',
    c_args: ['-D_GNU_SOURCE'],
    dependencies: [
        config_dep,
    ],
    native: true,
)

# Generate accessors code
accessors_ch_custom_tgt = custom_target(
    'accessors[.c.h.ld]',
    input: files(headers_to_scan),
    output: [
        generated_h,
        generated_c,
        generated_ld,
    ],
    command: [
        generate_accessors,
        '--h-out', '@OUTPUT0@',
        '--c-out', '@OUTPUT1@',
        '--ld-out', '@OUTPUT2@',
        '--incl', join_paths(meson.current_source_dir(), 'generate-accessors-include.list'),
        '--excl', join_paths(meson.current_source_dir(), 'generate-accessors-exclude.list'),
        '@INPUT@',
    ],
    build_by_default: true,
    install: true,
    install_dir: [
        get_option('includedir') / 'nvme',
        false,
        false,
    ],
    install_mode: 'rw-r--r--',
)

tgt_accessors_h = accessors_ch_custom_tgt[0]
tgt_accessors_c = accessors_ch_custom_tgt[1]
tgt_accessors_ld = accessors_ch_custom_tgt[2]

accessors_dep = declare_dependency(
    sources: [
        tgt_accessors_c,
        tgt_accessors_h,
    ],
    include_directories: '.',
    dependencies: [
        ccan_dep,
    ],
)

if meson.version().version_compare('>=1.4.0')
    accessors_ld_full_path = tgt_accessors_ld.full_path()
else
    accessors_ld_full_path = meson.current_build_dir() / generated_ld
endif