intellij-developer-tools-plugin/modules/tools/ui/build.gradle.kts at 1458ba438e9040409799e62be97f0fa26880b140 · marcelkliemannel/intellij-developer-tools-plugin · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71

import org.jetbrains.changelog.Changelog

plugins {
  `java-test-fixtures`
  alias(libs.plugins.changelog)
}

dependencies {
  implementation(project(":common"))
  implementation(project(":settings"))

  implementation(libs.commons.text)
  implementation(libs.commons.codec)
  implementation(libs.commons.io)
  implementation(libs.commons.compress)
  implementation(libs.jose4j)
  implementation(libs.bundles.jackson)
  implementation(libs.named.regexp)
  implementation(libs.bundles.zxing)
  implementation(libs.sql.formatter)
  implementation(libs.csscolor4j)
  implementation(libs.jfiglet)
  implementation(libs.jsonpath)
  implementation(libs.json.schema.validator) {
    exclude("org.apache.commons", "commons-lang3")
  }
  implementation(libs.bundles.text.case.converter)
  implementation(libs.ulid.creator)
  implementation(libs.jnanoid)
  implementation(libs.uuid.generator)
  implementation(libs.cronutils)
  implementation(libs.bcrypt)

  testImplementation(libs.assertj.core)
  testImplementation(libs.bundles.junit.implementation)
  testRuntimeOnly(libs.bundles.junit.runtime)
  testImplementation(testFixtures(project(":common")))

  testFixturesApi(project(":common"))
  testFixturesApi(project(":settings"))
}

changelog {
  path.set(rootProject.file("CHANGELOG.md").path)
}

val writeChangelogToFileTask =
  tasks.register("writeChangelogToFile") {
    val generatedResourcesDir = layout.buildDirectory.dir("generated-resources/changelog").get()
    outputs.dir(generatedResourcesDir)

    doLast {
      val renderResult =
        changelog.instance.get().releasedItems.joinToString("\n") {
          changelog.renderItem(it, Changelog.OutputType.HTML)
        }
      val baseDir = generatedResourcesDir.dir("dev/turingcomplete/intellijdevelopertoolsplugin")
      file(baseDir).mkdirs()
      file(baseDir.file("changelog.html")).writeText(renderResult)
    }
  }

sourceSets { main { resources { srcDir(writeChangelogToFileTask.map { it.outputs.files }) } } }

tasks.withType(org.jetbrains.changelog.tasks.InitializeChangelogTask::class).configureEach {
  enabled = false
}
tasks.withType(org.jetbrains.changelog.tasks.PatchChangelogTask::class).configureEach {
  enabled = false
}