nemo/libnemo-extension/meson.build at 9d265d73ee7754b99922a56978af79526a76e1ae · linuxmint/nemo · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99

nemo_i18n_header = [
  'nemo-extension-i18n.h'
]

nemo_extension_sources = [
  gresources,
  'nemo-action-layout-editor.c',
  'nemo-column-provider.c',
  'nemo-column.c',
  'nemo-desktop-preferences.c',
  'nemo-extension-private.h',
  'nemo-file-info.c',
  'nemo-info-provider.c',
  'nemo-location-widget-provider.c',
  'nemo-menu-item.c',
  'nemo-menu-provider.c',
  'nemo-name-and-desc-provider.c',
  'nemo-property-page-provider.c',
  'nemo-property-page.c',
  'nemo-menu.c',
  'nemo-simple-button.c',
]

nemo_extension_headers = [
  'nemo-action-layout-editor.h',
  'nemo-column-provider.h',
  'nemo-column.h',
  'nemo-desktop-preferences.h',
  'nemo-extension-types.h',
  'nemo-file-info.h',
  'nemo-info-provider.h',
  'nemo-location-widget-provider.h',
  'nemo-menu-item.h',
  'nemo-menu-provider.h',
  'nemo-name-and-desc-provider.h',
  'nemo-property-page-provider.h',
  'nemo-property-page.h',
  'nemo-menu.h',
  'nemo-simple-button.h',
]

nemo_extension_incdir = include_directories('.')

nemo_extension_deps = [ glib, gtk, json, xapp ]

nemo_extension_lib = shared_library('nemo-extension',
  nemo_extension_sources + nemo_i18n_header,
  dependencies: nemo_extension_deps,
  include_directories: [ rootInclude, ],
  install: true,
  version: '1.4.0',
  link_args: [ '-Wl,-no-undefined' ],
)

install_headers(nemo_extension_headers,
  subdir: join_paths('nemo', 'libnemo-extension')
)

nemo_extension = declare_dependency(
  include_directories: include_directories('.'),
  link_with: [ nemo_extension_lib ],
  dependencies: nemo_extension_deps,
)

typelibdir = go_intr.get_variable(pkgconfig: 'typelibdir',
  pkgconfig_define: ['libdir', join_paths(get_option('prefix'), get_option('libdir'))]
)

gnome.generate_gir(nemo_extension_lib,
  sources: nemo_extension_sources + nemo_extension_headers,
  nsversion: '3.0',
  namespace: 'Nemo',
  export_packages: 'libnemo-extension',
  includes: [ 'Gtk-3.0', 'Gio-2.0', 'GLib-2.0', ],
  include_directories: [ rootInclude, ],
  install_dir_typelib: typelibdir,
  install: true,
)

pkgconfig.generate(filebase: 'libnemo-extension',
  name: 'libnemo-extension',
  description: 'A library to create Nemo view extensions',
  version: meson.project_version(),
  requires: [ 'gio-2.0', 'glib-2.0', 'gtk+-3.0' ],
  libraries: nemo_extension_lib,
  subdirs: 'nemo',
  variables: 'extensiondir=${libdir}/@0@/@1@'.format('nemo', 'extensions-3.0'),
)

# Test executable for NemoActionLayoutEditor
test_action_layout_editor = executable('test-action-layout-editor',
  'test-action-layout-editor.c',
  dependencies: nemo_extension_deps,
  link_with: nemo_extension_lib,
  include_directories: [ rootInclude, nemo_extension_incdir ],
  build_by_default: true,
  install: false,
)