libnvme/accessors: Add framework to generate accessor code

This only adds the framework for code generation but leaves
the actual generation disabled for now.

Signed-off-by: Martin Belanger <[email protected]>

Author: Martin Belanger

libnvme/meson.build

@@ -238,6 +238,8 @@ conf.set(
     description: 'Is network address and service translation available'
 )
 
+conf.set('NVME_HAVE_SENDFILE', cc.has_function('sendfile'))
+
 threads_dep = dependency('threads', required: true)
 dl_dep = dependency('dl', required: false)
 conf.set(
@@ -293,6 +295,7 @@ incdir = include_directories(['.', 'ccan', 'src'])
 ################################################################################
 subdir('internal')
 subdir('ccan')
+#subdir('tools')
 subdir('src')
 subdir('libnvme')
 if get_option('tests')

libnvme/src/generated/meson.build

@@ -0,0 +1,58 @@
+# SPDX-License-Identifier: LGPL-2.1-or-later
+#
+# This file is part of libnvme.
+# Copyright (c) 2025, Dell Technologies Inc. or its subsidiaries.
+#
+# Authors: Martin Belanger <[email protected]>
+#
+# Run generate-accessors to generate the setter/getter functions.
+
+# List of header files to parse for structs
+headers_to_scan = [
+    '../nvme/private.h',
+]
+
+# Append full path to each member of headers_to_scan
+headers_to_scan_full_path = []
+foreach hdr : headers_to_scan
+    headers_to_scan_full_path += join_paths(meson.current_source_dir(), hdr)
+endforeach
+
+# Generate accessors.c and accessors.h
+accessors_ch_custom_tgt = custom_target(
+    'accessors.[ch]',
+    input: headers_to_scan_full_path,
+    output: [
+        'accessors.h',
+        'accessors.c',
+    ],
+    command: [
+        generate_accessors,
+        '--h-out', '@OUTPUT0@',
+        '--c-out', '@OUTPUT1@',
+        '--incl', join_paths(meson.current_source_dir(), 'structs-to-include.txt'),
+        '@INPUT@',
+    ],
+    build_by_default: true,
+    install: true,
+    install_dir: [
+        'nvme',       # Install @OUTPUT0@=='accessors.h' in this directory.
+        false,        # Do not install @OUTPUT1@=='accessors.c'
+    ],
+    install_mode: ['rw-r--r--', 0, 0],
+)
+
+generated_accessors_h = accessors_ch_custom_tgt[0]
+generated_accessors_c = accessors_ch_custom_tgt[1]
+
+if meson.version().version_compare('>=1.4.0')
+    generated_accessors_h_path = generated_accessors_h.full_path()
+else
+    generated_accessors_h_path = meson.current_build_dir() / 'accessor.h'
+endif
+
+generated_accessors_dep = declare_dependency(
+    sources: [
+        accessors_ch_custom_tgt,
+    ]
+)

libnvme/src/generated/structs-to-include.txt

@@ -0,0 +1,6 @@
+nvme_path
+nvme_ns
+nvme_ctrl
+nvme_subsystem
+nvme_host
+nvme_fabric_options