src: Generate accessor functions (setter/getter)

This adds the ability to automatically generate accessor functions
(setter/getter functions) by parsing structs definitions in header
files. Two files are generated: [accessors.c, accessors.h].

Signed-off-by: Martin Belanger <[email protected]>

Author: Martin Belanger

libnvme/internal/meson.build

@@ -20,5 +20,9 @@ config_dep = declare_dependency(
   include_directories : internal_incdir,
   sources: config_h)
 
-config_h_path = meson.current_build_dir() / 'config.h'
-config_h_arg =  [ '-include', config_h_path ]
+if meson.version().version_compare('>=1.4.0')
+  config_h_path = config_h.full_path()
+else
+  config_h_path = meson.current_build_dir() / 'config.h'
+endif
+

libnvme/meson.build

@@ -20,6 +20,8 @@ project(
     ]
 )
 
+fs = import('fs')
+
 vstr = meson.project_version().split('-rc')[0]
 vstr = vstr.split('.dev')[0]
 vid = vstr.split('.')
@@ -288,11 +290,12 @@ add_project_arguments(
     ],
     language : 'c',
 )
-incdir = include_directories(['.', 'ccan', 'src'])
+incdir = include_directories(['.', 'ccan', 'src', 'src/nvme'])
 
 ################################################################################
 subdir('internal')
 subdir('ccan')
+subdir('tools')
 subdir('src')
 subdir('libnvme')
 if get_option('tests')

libnvme/src/generated/meson.build

@@ -0,0 +1,58 @@
+# SPDX-License-Identifier: LGPL-2.1-or-later
+#
+# This file is part of libnvme.
+# Copyright (c) 2025, Dell Technologies Inc. or its subsidiaries.
+#
+# Authors: Martin Belanger <[email protected]>
+#
+# Run generate-accessors to generate the setter/getter functions.
+
+# List of header files to parse for structs
+headers_to_scan = [
+    '../nvme/private.h',
+]
+
+# Append full path to each member of headers_to_scan
+headers_to_scan_full_path = []
+foreach hdr : headers_to_scan
+    headers_to_scan_full_path += join_paths(meson.current_source_dir(), hdr)
+endforeach
+
+# Generate accessors.c and accessors.h
+accessors_ch_custom_tgt = custom_target(
+    'accessors.[ch]',
+    input: headers_to_scan_full_path,
+    output: [
+        'accessors.h',
+        'accessors.c',
+    ],
+    command: [
+        generate_accessors,
+        '--h-out', '@OUTPUT0@',
+        '--c-out', '@OUTPUT1@',
+        '--incl', join_paths(meson.current_source_dir(), 'structs-to-include.txt'),
+        '@INPUT@',
+    ],
+    build_by_default: true,
+    install: true,
+    install_dir: [
+        'nvme',       # Install @OUTPUT0@=='accessors.h' in this directory.
+        false,        # Do not install @OUTPUT1@=='accessors.c'
+    ],
+    install_mode: ['rw-r--r--', 0, 0],
+)
+
+generated_accessors_h = accessors_ch_custom_tgt[0]
+generated_accessors_c = accessors_ch_custom_tgt[1]
+
+if meson.version().version_compare('>=1.4.0')
+    generated_accessors_h_path = generated_accessors_h.full_path()
+else
+    generated_accessors_h_path = meson.current_build_dir() / 'accessors.h'
+endif
+
+generated_accessors_dep = declare_dependency(
+    sources: [
+        accessors_ch_custom_tgt,
+    ]
+)

libnvme/src/generated/structs-to-include.txt

@@ -0,0 +1,6 @@
+nvme_path
+nvme_ns
+nvme_ctrl
+nvme_subsystem
+nvme_host
+nvme_fabric_options

libnvme/src/meson.build

@@ -27,12 +27,18 @@ else
     sources += 'nvme/no-json.c'
 endif
 
+# Generate accessors (setter/getter functions)
+subdir('generated')
+sources += generated_accessors_c
+
 deps = [
     json_c_dep,
     keyutils_dep,
     libdbus_dep,
     liburing_dep,
     openssl_dep,
+    config_dep,
+    generated_accessors_dep,
 ]
 
 source_dir = meson.current_source_dir()
@@ -46,8 +52,11 @@ libnvme = library(
     link_args: ['-Wl,--version-script=' + version_script_arg],
     dependencies: deps,
     link_depends: mapfile,
-    c_args: config_h_arg,
-    include_directories: [incdir, internal_incdir],
+    c_args: [
+        '-include', config_h_path,
+        '-include', generated_accessors_h_path,
+    ],
+    include_directories: [incdir, ],
     install: true,
     link_with: libccan,
 )
@@ -75,8 +84,11 @@ libnvme_test = library(
     'nvme-test', # produces libnvme-test.so
     sources,
     dependencies: deps,
-    c_args: config_h_arg,
-    include_directories: [incdir, internal_incdir],
+    c_args: [
+        '-include', config_h_path,
+        '-include', generated_accessors_h_path,
+    ],
+    include_directories: [incdir, ],
     install: false,
     link_with: libccan,
 )