test: add header include test

Add a simple test which ensures that all headers are self contained and
don't have an undocumented dependency.

Signed-off-by: Daniel Wagner <[email protected]>

Author: igaw

libnvme/test/meson.build

@@ -176,3 +176,30 @@ if openssl_dep.found()
         dependencies: openssl_dep,
     )
 endif
+
+foreach hdr : [
+    'fabrics',
+    'filters',
+    'ioctl',
+    'linux',
+    'log',
+    'mi',
+    'nbft',
+    'tree',
+    'types',
+    'util',
+]
+    hdr_conf = configuration_data()
+    hdr_conf.set('HDR', hdr)
+    src = configure_file(
+        input: 'test-header.c.in',
+        output: 'test-header-' + hdr + '.c',
+        configuration: hdr_conf,
+    )
+    exe = executable(
+        'test-header-' + hdr,
+        src,
+        dependencies: [libnvme_dep],
+    )
+    test('libnvme - header/' + hdr, exe)
+endforeach

libnvme/test/test-header.c.in

@@ -0,0 +1,11 @@
+// SPDX-License-Identifier: LGPL-2.1-or-later
+/*
+ * Verify that <nvme/@[email protected]> is self-sufficient: it can be included
+ * as the very first (and only) header without any prior includes.
+ */
+#include <nvme/@[email protected]>
+
+int main(void)
+{
+	return 0;
+}