emulate FetchContent to not require CMake 3.11; closes #29

Author: bast

test/CMakeLists.txt

@@ -1,25 +1,20 @@
 # copy reference file to ${PROJECT_BINARY_DIR}/test (aka ${CMAKE_CURRENT_BINARY_DIR})
 file(COPY reference_grid.txt DESTINATION ${CMAKE_CURRENT_BINARY_DIR})
 
-include(FetchContent)
+include(fetch_git_repo.cmake)
 
-FetchContent_Declare(
+fetch_git_repo(
   googletest
-  GIT_REPOSITORY https://github.com/google/googletest.git
-  GIT_TAG        release-1.8.0
+  ${CMAKE_BINARY_DIR}/_deps
+  https://github.com/google/googletest.git
+  release-1.8.0
 )
 
-FetchContent_GetProperties(googletest)
-
-if(NOT googletest_POPULATED)
-  FetchContent_Populate(googletest)
-
-  # adds the targers: gtest, gtest_main, gmock, gmock_main
-  add_subdirectory(
-    ${googletest_SOURCE_DIR}
-    ${googletest_BINARY_DIR}
-    )
-endif()
+# adds the targers: gtest, gtest_main, gmock, gmock_main
+add_subdirectory(
+  ${googletest_SOURCE_DIR}
+  ${googletest_BINARY_DIR}
+  )
 
 add_executable(
   cpp_test

test/fetch_at_configure_step.in

@@ -0,0 +1,19 @@
+cmake_minimum_required(VERSION 3.5 FATAL_ERROR)
+
+project(fetch_git_repo_sub LANGUAGES NONE)
+
+include(ExternalProject)
+
+ExternalProject_Add(
+  @FETCH_PROJECT_NAME@
+  SOURCE_DIR "@FETCH_SOURCE_DIR@"
+  BINARY_DIR "@FETCH_BINARY_DIR@"
+  GIT_REPOSITORY
+    @FETCH_GIT_REPOSITORY@
+  GIT_TAG
+    @FETCH_GIT_TAG@
+  CONFIGURE_COMMAND ""
+  BUILD_COMMAND ""
+  INSTALL_COMMAND ""
+  TEST_COMMAND ""
+  )

test/fetch_git_repo.cmake

@@ -0,0 +1,45 @@
+# the following code to fetch a git repo at configure-time
+# is inspired by and adapted after https://crascit.com/2015/07/25/cmake-gtest/
+# defines ${_project_name}_SOURCE_DIR and ${_project_name}_BINARY_DIR
+
+macro(fetch_git_repo _project_name _download_root _git_url _git_tag)
+
+  set(${_project_name}_SOURCE_DIR ${_download_root}/${_project_name}-src)
+  set(${_project_name}_BINARY_DIR ${_download_root}/${_project_name}-build)
+
+  # variables used configuring fetch_git_repo_sub.cmake
+  set(FETCH_PROJECT_NAME ${_project_name})
+  set(FETCH_SOURCE_DIR ${${_project_name}_SOURCE_DIR})
+  set(FETCH_BINARY_DIR ${${_project_name}_BINARY_DIR})
+  set(FETCH_GIT_REPOSITORY ${_git_url})
+  set(FETCH_GIT_TAG ${_git_tag})
+
+  configure_file(
+    ${CMAKE_CURRENT_LIST_DIR}/fetch_at_configure_step.in
+    ${_download_root}/CMakeLists.txt
+    @ONLY
+    )
+
+  # undefine them again
+  unset(FETCH_PROJECT_NAME)
+  unset(FETCH_SOURCE_DIR)
+  unset(FETCH_BINARY_DIR)
+  unset(FETCH_GIT_REPOSITORY)
+  unset(FETCH_GIT_TAG)
+
+  # configure sub-project
+  execute_process(
+    COMMAND
+      "${CMAKE_COMMAND}" -G "${CMAKE_GENERATOR}" .
+    WORKING_DIRECTORY
+      ${_download_root}
+    )
+
+  # build sub-project which triggers ExternalProject_Add
+  execute_process(
+    COMMAND
+      "${CMAKE_COMMAND}" --build .
+    WORKING_DIRECTORY
+      ${_download_root}
+    )
+endmacro()