Relocate tool-generated source files to build/generated/sources

Author: danijelaskov

.github/workflows/gradle.yml

@@ -11,14 +11,14 @@ on:
     branches: [ "master" ]
     paths:
       - "src/**"
-      - "build.gradle"
+      - "build.gradle.kts"
       - "gradle/**"
       - ".github/workflows/gradle.yml"
   pull_request:
     branches: [ "master" ]
     paths:
       - "src/**"
-      - "build.gradle"
+      - "build.gradle.kts"
       - "gradle/**"
       - ".github/workflows/gradle.yml"
 permissions:

README.md

@@ -93,8 +93,8 @@ MicroJava's single line comment starts with two forward slashes with no white sp
 To build and test this project you will need [Java 17](https://adoptium.net/temurin/) (the latest LTS release as of February 2023) and [Gradle 7.3](https://docs.gradle.org/current/userguide/userguide.html).
 Open command-line interpreter and type one of the following commands:
 
-* `gradlew genLexer` (Windows) or `./gradlew genLexer` (macOS and Linux) — to generate lexer (tokenizer) implementation ([`MJLexer.java`](src/main/java/dev/askov/mjcompiler/MJLexer.java)) based on [lexer specification](src/main/spec/mjlexer.flex).
-* `gradlew genParser` (Windows) or `./gradlew genParser` (macOS and Linux) — to generate parser implementation ([`MJParser.java`](src/main/java/dev/askov/mjcompiler/MJParser.java), [`sym.java`](src/main/java/dev/askov/mjcompiler/sym.java)) and abstract syntax tree implementation (classes inside [`ast`](src/main/java/dev/askov/mjcompiler/ast) directory), based on [parser specification](src/main/spec/mjparser.cup).
+* `gradlew lexer` (Windows) or `./gradlew lexer` (macOS and Linux) — to generate lexer (tokenizer) implementation (`MJLexer.java`) based on [lexer specification](src/main/resources/mjlexer.flex).
+* `gradlew parser` (Windows) or `./gradlew parser` (macOS and Linux) — to generate parser implementation (`MJParser.java`, `sym.java`) and abstract syntax tree implementation (classes inside `ast` directory), based on [parser specification](src/main/resources/mjparser.cup).
 * `gradlew build` (Windows) or `./gradlew build` (macOS and Linux) — to build the project, test the compiler and run MicroJava VM. MicroJava Compiler will compile the test file [`simple_calculator.mj`](src/test/resources/simple_calculator.mj) and produce `simple_calculator.obj`. Then, the machine code inside `simple_calculator.obj` will be executed by MicroJava VM.
 Note that, for testing purposes, standard input has been substituted with a file named [`input_stream.txt`](src/test/resources/input_stream.txt).
 * `gradlew disassemble` (Windows) or `./gradlew disassemble` (macOS and Linux) — to disassemble `simple_calculator.obj` produced in the previous step, using [`rs.etf.pp1.mj.runtime.disasm`](libs/mj-runtime-1.1.jar).

build.gradle

@@ -0,0 +1,109 @@
+plugins {
+    java
+    application
+}
+
+group = "dev.askov.mjcompiler"
+version = "1.0"
+
+java {
+    toolchain {
+        languageVersion.set(JavaLanguageVersion.of(25))
+    }
+}
+
+application {
+    mainClass.set("dev.askov.mjcompiler.MJCompiler")
+}
+
+repositories {
+    mavenCentral()
+    flatDir {
+        dirs("libs")
+    }
+}
+
+dependencies {
+    testImplementation("junit:junit:4.13.1")
+
+    // Using flatDir dependencies (lookup by name only)
+    implementation(":JFlex")
+    implementation(":cup_v10k")
+    implementation(":log4j-1.2.17")
+    implementation(":mj-runtime-1.1")
+    implementation(":symboltable")
+}
+
+tasks.test {
+    testLogging {
+        outputs.upToDateWhen { false }
+        showStandardStreams = true
+    }
+}
+
+val jflexDir = layout.buildDirectory.dir("generated/sources/jflex/java/main").get()
+val cupDir = layout.buildDirectory.dir("generated/sources/cup/java/main").get()
+
+sourceSets.main {
+    java.srcDirs(jflexDir, cupDir)
+}
+
+tasks.register<JavaExec>("lexer") {
+    group = "generation"
+    mainClass.set("JFlex.Main")
+    classpath = sourceSets.main.get().compileClasspath
+
+    val outputFile = jflexDir.file("dev/askov/mjcompiler/MJLexer.java")
+
+    inputs.file("src/main/resources/mjlexer.flex")
+    outputs.file(outputFile)
+
+    args("-d", outputFile.asFile.parent, "src/main/resources/mjlexer.flex")
+}
+
+tasks.register<JavaExec>("parser") {
+    group = "generation"
+    dependsOn("lexer")
+    mainClass.set("java_cup.Main")
+    classpath = sourceSets.main.get().compileClasspath.minus(files("libs/JFlex.jar"))
+
+    val genSourceRoot = cupDir.asFile
+
+    workingDir = genSourceRoot
+
+    inputs.file("src/main/resources/mjparser.cup")
+    outputs.dir(genSourceRoot)
+
+    doFirst {
+        file("${cupDir.asFile.path}/dev/askov/mjcompiler").mkdirs()
+    }
+
+    args(
+        "-destdir", "dev/askov/mjcompiler",
+        "-parser", "MJParser",
+        "-ast", "dev.askov.mjcompiler.ast",
+        "-buildtree",
+        file("src/main/resources/mjparser.cup").absolutePath
+    )
+}
+
+tasks.compileJava {
+    dependsOn("lexer", "parser")
+}
+
+tasks.clean {
+    delete(
+        "src/main/java/dev/askov/mjcompiler/MJLexer.java",
+        "src/main/java/dev/askov/mjcompiler/MJParser.java",
+        "src/main/java/dev/askov/mjcompiler/sym.java",
+        "src/main/java/dev/askov/mjcompiler/ast"
+    )
+}
+
+tasks.register<JavaExec>("disassemble") {
+    group = "verification"
+
+    mainClass.set("rs.etf.pp1.mj.runtime.disasm")
+    classpath = sourceSets.main.get().runtimeClasspath
+    args("src/test/resources/simple_calculator.obj")
+}