feat: add initial ANTLR grammar for JPP

Author: AlexanderSchultheiss

src/main/antlr4/org/variantsync/diffdetective/feature/antlr/JPPExpression.g4

@@ -0,0 +1,320 @@
+grammar JPPExpression;
+// A grammar for the JavaPreprocessor
+// https://www.slashdev.ca/javapp/
+
+jppExpression
+    :   logicalOrExpression
+    ;
+
+logicalOrExpression
+    :   logicalAndExpression (OR logicalAndExpression)*
+    ;
+
+logicalAndExpression
+    :   expression (AND expression)*
+    ;
+
+expression
+    :   definedExpression
+    |   undefinedExpression
+    |   comparisonExpression
+    ;
+
+comparisonExpression
+    :   operand ((LT|GT|LEQ|GEQ|EQ|NEQ) operand)?
+    ;
+
+operand
+    :   propertyExpression
+    |   Constant
+    |   StringLiteral+
+    |   unaryOperator Constant
+    ;
+
+definedExpression
+    :   'defined' '(' Identifier ')'
+    ;
+
+undefinedExpression
+    :   NOT 'defined' '(' Identifier ')'
+    ;
+
+propertyExpression
+    :   '${' Identifier '}'
+    ;
+
+unaryOperator
+    : U_PLUS
+    | U_MINUS
+    ;
+
+U_PLUS : '+';
+U_MINUS : '-';
+
+AND : 'and';
+OR  : 'or';
+NOT : '!';
+
+LT : '<';
+LEQ : '<=';
+GT : '>';
+GEQ : '>=';
+
+EQ : '==';
+NEQ : '!=';
+
+DOT : '.';
+
+Identifier
+    :   ('\\')? (   IdentifierNondigit
+        |   Digit
+        )+
+    ;
+
+fragment
+IdentifierNondigit
+    :   Nondigit
+    |   UniversalCharacterName
+    //|   // other implementation-defined characters...y
+    ;
+
+fragment
+Nondigit
+    :   [a-zA-Z_]
+    ;
+
+fragment
+Digit
+    :   [0-9]
+    ;
+
+fragment
+UniversalCharacterName
+    :   '\\u' HexQuad
+    |   '\\U' HexQuad HexQuad
+    ;
+
+fragment
+HexQuad
+    :   HexadecimalDigit HexadecimalDigit HexadecimalDigit HexadecimalDigit
+    ;
+
+Constant
+    :   IntegerConstant
+    |   FloatingConstant
+    ;
+
+fragment
+IntegerConstant
+    :   DecimalConstant IntegerSuffix?
+    |   OctalConstant IntegerSuffix?
+    |   HexadecimalConstant IntegerSuffix?
+    |	BinaryConstant
+    ;
+
+fragment
+BinaryConstant
+	:	'0' [bB] [0-1]+
+	;
+
+fragment
+DecimalConstant
+    :   NonzeroDigit Digit*
+    ;
+
+fragment
+OctalConstant
+    :   '0' OctalDigit*
+    ;
+
+fragment
+HexadecimalConstant
+    :   HexadecimalPrefix HexadecimalDigit+
+    ;
+
+fragment
+HexadecimalPrefix
+    :   '0' [xX]
+    ;
+
+fragment
+NonzeroDigit
+    :   [1-9]
+    ;
+
+fragment
+OctalDigit
+    :   [0-7]
+    ;
+
+fragment
+HexadecimalDigit
+    :   [0-9a-fA-F]
+    ;
+
+fragment
+IntegerSuffix
+    :   UnsignedSuffix LongSuffix?
+    |   UnsignedSuffix LongLongSuffix
+    |   LongSuffix UnsignedSuffix?
+    |   LongLongSuffix UnsignedSuffix?
+    ;
+
+fragment
+UnsignedSuffix
+    :   [uU]
+    ;
+
+fragment
+LongSuffix
+    :   [lL]
+    ;
+
+fragment
+LongLongSuffix
+    :   'll' | 'LL'
+    ;
+
+fragment
+FloatingConstant
+    :   DecimalFloatingConstant
+    |   HexadecimalFloatingConstant
+    ;
+
+fragment
+DecimalFloatingConstant
+    :   FractionalConstant ExponentPart? FloatingSuffix?
+    |   DigitSequence ExponentPart FloatingSuffix?
+    ;
+
+fragment
+HexadecimalFloatingConstant
+    :   HexadecimalPrefix (HexadecimalFractionalConstant | HexadecimalDigitSequence) BinaryExponentPart FloatingSuffix?
+    ;
+
+fragment
+FractionalConstant
+    :   DigitSequence? '.' DigitSequence
+    |   DigitSequence '.'
+    ;
+
+fragment
+ExponentPart
+    :   [eE] Sign? DigitSequence
+    ;
+
+fragment
+Sign
+    :   [+-]
+    ;
+
+DigitSequence
+    :   Digit+
+    ;
+
+fragment
+HexadecimalFractionalConstant
+    :   HexadecimalDigitSequence? '.' HexadecimalDigitSequence
+    |   HexadecimalDigitSequence '.'
+    ;
+
+fragment
+BinaryExponentPart
+    :   [pP] Sign? DigitSequence
+    ;
+
+fragment
+HexadecimalDigitSequence
+    :   HexadecimalDigit+
+    ;
+
+fragment
+FloatingSuffix
+    :   [flFL]
+    ;
+
+
+fragment
+CCharSequence
+    :   CChar+
+    ;
+
+fragment
+CChar
+    :   ~['\\\r\n]
+    |   EscapeSequence
+    ;
+
+fragment
+EscapeSequence
+    :   SimpleEscapeSequence
+    |   OctalEscapeSequence
+    |   HexadecimalEscapeSequence
+    |   UniversalCharacterName
+    ;
+
+fragment
+SimpleEscapeSequence
+    :   '\\' ['"?abfnrtv\\]
+    ;
+
+fragment
+OctalEscapeSequence
+    :   '\\' OctalDigit OctalDigit? OctalDigit?
+    ;
+
+fragment
+HexadecimalEscapeSequence
+    :   '\\x' HexadecimalDigit+
+    ;
+
+StringLiteral
+    :   EncodingPrefix? '"' SCharSequence? '"'
+    ;
+
+fragment
+EncodingPrefix
+    :   'u8'
+    |   'u'
+    |   'U'
+    |   'L'
+    ;
+
+fragment
+SCharSequence
+    :   SChar+
+    ;
+
+fragment
+SChar
+    :   ~["\\\r\n]
+    |   EscapeSequence
+    |   '\\\n'   // Added line
+    |   '\\\r\n' // Added line
+    ;
+
+Whitespace
+    :   [ \t]+ -> channel(HIDDEN)
+    ;
+
+Newline
+    :   (   '\r' '\n'?
+        |   '\n'
+        )
+        -> channel(HIDDEN)
+    ;
+
+BlockComment
+    :   '/*' .*? '*/'
+        -> channel(HIDDEN)
+    ;
+
+OpenBlockComment
+    :  '/*' ~[*/]*
+        -> channel(HIDDEN)
+        ;
+
+LineComment
+    :   '//' ~[\r\n]*
+        -> channel(HIDDEN)
+    ;