feat: nix flake for export CLI tool

feat: nix flake for export CLI tool

Author: gergely-szabo-sap

.github/workflows/flake-check.yaml

@@ -0,0 +1,52 @@
+on:
+  pull_request:
+
+jobs:
+  flake-check:
+    permissions:
+      contents: read
+    name: Check nix flakes
+    runs-on: ubuntu-latest
+    steps:
+      - uses: actions/checkout@692973e3d937129bcbf40652eb9f2f61becf3332 # v4.1.7
+      - name: Check Nix flake inputs
+        uses: DeterminateSystems/flake-checker-action@main
+        with:
+          check-outdated: false
+      - uses: cachix/install-nix-action@4e002c8ec80594ecd40e759629461e26c8abed15 # version v31.9.0
+      - name: Check flake
+        run: |
+          nix flake check
+
+  vendor-hash-check:
+    permissions:
+      contents: read
+    name: Comparing vendor hash values
+    runs-on: ubuntu-latest
+    steps:
+      - uses: actions/checkout@692973e3d937129bcbf40652eb9f2f61becf3332 # v4.1.7
+      - name: Check Nix flake inputs
+        uses: DeterminateSystems/flake-checker-action@main
+        with:
+          check-outdated: false
+      - uses: cachix/install-nix-action@4e002c8ec80594ecd40e759629461e26c8abed15 # version v31.9.0
+      - name: Get vendor directory
+        run: |
+          nix develop . -c go mod vendor
+      - id: calculated-hash
+        name: Calculate vendor hash
+        run: |
+          hash=$(nix hash path vendor)
+          echo "Calculated vendor hash: $hash"
+          echo "HASH=$hash" >> "$GITHUB_OUTPUT"
+      - id: current-hash
+        name: Get the current vendor hash
+        run: |
+          hash=$(nix eval --file ./config.nix --raw --argstr lib '' 'exporter-cli.vendorHash' --raw)
+          echo "Configured vendor hash: $hash"
+          echo "HASH=$hash" >> "$GITHUB_OUTPUT"
+      - name: Comparing hashes
+        if: ${{ steps.calculated-hash.outputs.HASH != steps.current-hash.outputs.HASH }}
+        run: |
+          echo "::error file=config.nix,line=6,title=Invalid vendorHash::Update the vendor hash. Suggested value: ${{steps.calculated-hash.outputs.HASH}}"
+          exit 1

cmd/exporter/docs/USERGUIDE.md

@@ -7,6 +7,19 @@ The `xpcf` tool observes *Cloud Foundry* resources and exports them as managed C
 
 # TODO Installation
 
+## Nix users
+
+Nix users can easily execute the `xpcf` tool using the following command:
+
+```bash
+nix run github:SAP/crossplane-provider-cloudfoundry/<version>#xpcf -- <flags>
+```
+
+To get the *help* for version v0.3.4, execute
+
+```bash
+nix run github:SAP/crossplane-provider-cloudfoundry/v0.3.4#xpcf -- --help
+```
 
 # Quick Start
 

config.nix

@@ -0,0 +1,24 @@
+{ lib }:
+{
+  exporter-cli = {
+    name = "xpcf";
+    version = "0.0.1-alpha1";
+    vendorHash = "sha256-HiWXSvLwRzt1/wMl2LQfwrBPoRpsl5E3TsN/1N0PGWs=";
+    meta = {
+      description = "xpcf is a CLI tool for exporting existing resources as Crossplane managed resources";
+      homepage = "https://github.com/SAP/crossplane-provider-cloudfoundry";
+      license = lib.licenses.asl20;
+    };
+    src = with lib; fileset.toSource {
+      root = ./.;
+      fileset = fileset.unions [
+        (fileset.fromSource (sources.sourceFilesBySuffices ./. [".go"]))
+        ./go.mod
+        ./go.sum
+        ./flake.nix
+        ./flake.lock
+        ./config.nix
+      ];
+    };
+  };
+}

flake.lock

@@ -0,0 +1,50 @@
+{
+  description = "Description for the project";
+
+  inputs = {
+    flake-parts.url = "github:hercules-ci/flake-parts";
+    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
+  };
+
+  outputs = inputs@{ flake-parts, ... }:
+    flake-parts.lib.mkFlake { inherit inputs; } {
+      imports = [
+      ];
+      systems = [ "x86_64-linux" "aarch64-linux" "aarch64-darwin" "x86_64-darwin" ];
+      perSystem = { config, self', inputs', pkgs, lib, system, ... }:
+        let
+          config = import ./config.nix { inherit lib; };
+        in
+          {
+            packages = rec {
+              exporter = pkgs.buildGoModule {
+                inherit (config.exporter-cli) version;
+                pname = config.exporter-cli.name;
+                ldflags = ["-X main.ShortName=${config.exporter-cli.name}"];
+                src = config.exporter-cli.src;
+                subPackages = ["cmd/exporter"];
+                vendorHash = config.exporter-cli.vendorHash;
+                meta = config.exporter-cli.meta;
+              };
+              "${config.exporter-cli.name}" = pkgs.runCommand "${config.exporter-cli.name}" {} ''
+              mkdir -p $out/bin
+              cp ${exporter}/bin/exporter $out/bin/${config.exporter-cli.name}
+            '';
+            };
+            devShells.default = pkgs.mkShell {
+              packages = with pkgs; [go];
+            };
+            apps.exporter = {
+              meta = config.exporter-cli.meta;
+              type = "app";
+              program = "${self'.packages.${config.exporter-cli.name}}/bin/${config.exporter-cli.name}";
+            };
+            checks = {
+              exporter = pkgs.runCommand "exporter-help" {} ''
+                     ${self'.packages.${config.exporter-cli.name}}/bin/${config.exporter-cli.name} --help > $out
+            '';
+            };
+          };
+      flake = {};
+    };
+}