nvme-cli/libnvme/test/meson.build at 8902a885112a63ca2196d8e159645c0998afd49b · Micron-TPG-OSS/nvme-cli · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
# SPDX-License-Identifier: LGPL-2.1-or-later
#
# This file is part of libnvme.
# Copyright (c) 2021 Dell Inc.
#
# Authors: Martin Belanger <[email protected]>

python3_prog = find_program('python3', required: false)
if python3_prog.found()
    test(
        'libnvme - check-public-symbols',
        python3_prog,
        args: [
            files('../tools/check-public-symbols.py'),
            meson.project_source_root() / 'libnvme',
        ],
    )
endif

# These tests all require interaction with a real NVMe device, so we don't
# define as meson unit-tests, and therefore get run as part of the 'test'
# target. However, they're available for developer use, when hardware is
# available.
main = executable(
    'main-test',
    ['test.c'],
    dependencies: [
        config_dep,
        ccan_dep,
        libnvme_test_dep,
    ],
)

if cxx_available
    cpp = executable(
        'test-cpp',
        ['cpp.cc'],
        dependencies: [
            config_dep,
            ccan_dep,
            libnvme_dep,
        ],
    )

    test('libnvme - cpp-dump', cpp)

    misc = executable(
        'test-misc',
        ['misc.cc'],
        dependencies: [
            config_dep,
            ccan_dep,
            libnvme_dep,
        ],
    )
    test('libnvme - cpp-misc', misc)

endif

register = executable(
    'test-register',
    ['register.c'],
    dependencies: [
        config_dep,
        ccan_dep,
        libnvme_dep,
    ],
)

zns = executable(
    'test-zns',
    ['zns.c'],
    dependencies: [
        config_dep,
        ccan_dep,
        libnvme_test_dep,
    ],
)

if want_mi
    mi = executable(
        'test-mi',
        ['mi.c', 'utils.c'],
        dependencies: [
            config_dep,
            ccan_dep,
            libnvme_test_dep,
        ],
    )

    test('libnvme - mi', mi)

    mi_mctp = executable(
        'test-mi-mctp',
        ['mi-mctp.c', 'utils.c'],
        dependencies: [
            config_dep,
            ccan_dep,
            libnvme_test_dep,
        ],
    )

    test('libnvme - mi-mctp', mi_mctp)
endif

uuid = executable(
    'test-uuid',
    ['uuid.c'],
    dependencies: [
        config_dep,
        ccan_dep,
        libnvme_dep,
    ],
)

test('libnvme - uuid', uuid)

if want_fabrics
    uriparser = executable(
        'test-uriparser',
        ['uriparser.c'],
        dependencies: [
            config_dep,
            ccan_dep,
            libnvme_dep,
        ],
    )

test('libnvme - uriparser', uriparser)
endif

if conf.get('HAVE_NETDB')
    mock_ifaddrs = library(
        'mock-ifaddrs',
        ['mock-ifaddrs.c', ],
    )

    # See comment in test/ioctl/meson.build explaining how LD_PRELOAD is used
    mock_ifaddrs_env = environment()
    mock_ifaddrs_env.append('LD_PRELOAD', mock_ifaddrs.full_path())
    mock_ifaddrs_env.set('ASAN_OPTIONS', 'verify_asan_link_order=0')

    tree = executable(
        'tree',
        ['tree.c'],
        dependencies: [
            config_dep,
            ccan_dep,
            libnvme_test_dep,
        ],
        link_with: mock_ifaddrs,
    )

    test('libnvme - tree', tree, env: mock_ifaddrs_env)

    test_util = executable(
        'test-util',
        ['test-util.c'],
        dependencies: [
            config_dep,
            ccan_dep,
            libnvme_test_dep,
        ],
    )
    test('libnvme - util', test_util)
endif

psk = executable(
    'test-psk',
    ['psk.c'],
    dependencies: [
        config_dep,
        ccan_dep,
        libnvme_dep,
    ],
)

test('libnvme - psk', psk)

subdir('ioctl')
if want_fabrics
    subdir('nbft')
endif

if json_c_dep.found()
    subdir('sysfs')
    subdir('config')
endif

if openssl_dep.found()
    hkdf_add1 = executable(
        'hkdf_add1',
        ['hkdf_add1.c'],
        dependencies: openssl_dep,
    )
endif

foreach hdr : [
    'endian',
    'fabrics',
    'filters',
    'ioctl',
    'lib',
    'lib-types',
    'linux',
    'mi',
    'nbft',
    'nvme-cmds',
    'nvme-types',
    'tree',
    'util',
]
    hdr_conf = configuration_data()
    hdr_conf.set('HDR', hdr)
    src = configure_file(
        input: 'test-header.c.in',
        output: 'test-header-' + hdr + '.c',
        configuration: hdr_conf,
    )
    exe = executable(
        'test-header-' + hdr,
        src,
        dependencies: [libnvme_dep],
    )
    test('libnvme - header/' + hdr, exe)
endforeach