[Backport to 22] Add SPV_INTEL_subgroup_buffer_prefetch extension support (#3690) (#3694)

cherry picked from c8862dd

Author: vmaksimo

include/LLVMSPIRVExtensions.inc

@@ -72,6 +72,7 @@ EXT(SPV_INTEL_fpga_argument_interfaces)
 EXT(SPV_INTEL_fpga_latency_control)
 EXT(SPV_INTEL_fp_max_error)
 EXT(SPV_INTEL_cache_controls)
+EXT(SPV_INTEL_subgroup_buffer_prefetch)
 EXT(SPV_INTEL_subgroup_requirements)
 EXT(SPV_INTEL_task_sequence)
 EXT(SPV_INTEL_maximum_registers)

lib/SPIRV/SPIRVUtil.cpp

@@ -2493,6 +2493,12 @@ class SPIRVFriendlyIRMangleInfo : public BuiltinFuncMangleInfo {
       setArgAttr(0, SPIR::ATTR_CONST);
       addUnsignedArg(0);
       break;
+    case OpSubgroupBlockPrefetchINTEL:
+      setArgAttr(0, SPIR::ATTR_CONST);
+      addUnsignedArg(0);
+      addUnsignedArg(1);
+      addUnsignedArg(2); // optional Memory Operands bitmask
+      break;
     case OpAtomicUMax:
     case OpAtomicUMin:
       addUnsignedArg(0);

lib/SPIRV/libSPIRV/SPIRVInstruction.h

@@ -4392,6 +4392,46 @@ class SPIRVUntypedPrefetchKHR : public SPIRVInstruction {
   std::vector<SPIRVId> CacheTy;
 };
 
+class SPIRVSubgroupBlockPrefetchINTELInst : public SPIRVInstTemplateBase {
+public:
+  std::optional<ExtensionID> getRequiredExtension() const override {
+    return ExtensionID::SPV_INTEL_subgroup_buffer_prefetch;
+  }
+  SPIRVCapVec getRequiredCapability() const override {
+    return getVec(CapabilitySubgroupBufferPrefetchINTEL);
+  }
+  // Operand 2, if present, is the Memory Operands bitmask.
+  bool isOperandLiteral(unsigned I) const override { return I == 2; }
+
+protected:
+  void validate() const override {
+    SPIRVInstruction::validate();
+    if (getValue(Ops[0])->isForward())
+      return;
+    SPIRVErrorLog &SPVErrLog = getModule()->getErrorLog();
+    SPIRVType *PtrType = getValueType(Ops[0]);
+    std::string InstName = "OpSubgroupBlockPrefetchINTEL";
+    SPVErrLog.checkError(
+        PtrType->isTypePointer() || PtrType->isTypeUntypedPointerKHR(),
+        SPIRVEC_InvalidInstruction, InstName + "\nPtr must be a pointer\n");
+    SPVErrLog.checkError(
+        PtrType->getPointerStorageClass() == StorageClassCrossWorkgroup,
+        SPIRVEC_InvalidInstruction,
+        InstName + "\nPtr must be in CrossWorkgroup storage class\n");
+    if (!PtrType->isTypeUntypedPointerKHR())
+      SPVErrLog.checkError(PtrType->getPointerElementType()->isTypeInt(),
+                           SPIRVEC_InvalidInstruction,
+                           InstName +
+                               "\nPtr must point to a scalar integer type\n");
+    SPVErrLog.checkError(
+        getValueType(Ops[1])->isTypeInt(32), SPIRVEC_InvalidInstruction,
+        InstName + "\nNumBytes must be a 32-bit integer scalar\n");
+  }
+};
+typedef SPIRVInstTemplate<SPIRVSubgroupBlockPrefetchINTELInst,
+                          OpSubgroupBlockPrefetchINTEL, false, 3, true>
+    SPIRVSubgroupBlockPrefetchINTEL;
+
 class SPIRVSubgroup2DBlockIOINTELInst : public SPIRVInstTemplateBase {
 public:
   std::optional<ExtensionID> getRequiredExtension() const override {

lib/SPIRV/libSPIRV/SPIRVNameMapEnum.h

@@ -563,6 +563,7 @@ template <> inline void SPIRVMap<Capability, std::string>::init() {
   add(CapabilityBindlessTextureNV, "BindlessTextureNV");
   add(CapabilitySubgroupShuffleINTEL, "SubgroupShuffleINTEL");
   add(CapabilitySubgroupBufferBlockIOINTEL, "SubgroupBufferBlockIOINTEL");
+  add(CapabilitySubgroupBufferPrefetchINTEL, "SubgroupBufferPrefetchINTEL");
   add(CapabilitySubgroupImageBlockIOINTEL, "SubgroupImageBlockIOINTEL");
   add(CapabilitySubgroupImageMediaBlockIOINTEL,
       "SubgroupImageMediaBlockIOINTEL");

lib/SPIRV/libSPIRV/SPIRVOpCodeEnum.h

@@ -574,6 +574,7 @@ _SPIRV_OP(ConvertBF16ToFINTEL, 6117)
 _SPIRV_OP(ControlBarrierArriveINTEL, 6142)
 _SPIRV_OP(ControlBarrierWaitINTEL, 6143)
 _SPIRV_OP(ArithmeticFenceEXT, 6145)
+_SPIRV_OP(SubgroupBlockPrefetchINTEL, 6221)
 _SPIRV_OP(Subgroup2DBlockLoadINTEL, 6231)
 _SPIRV_OP(Subgroup2DBlockLoadTransformINTEL, 6232)
 _SPIRV_OP(Subgroup2DBlockLoadTransposeINTEL, 6233)

test/extensions/INTEL/SPV_INTEL_subgroup_buffer_prefetch/negative_invalid_elem_type.spt

@@ -0,0 +1,30 @@
+; RUN: not llvm-spirv %s -to-binary -o %t.spv 2>&1 | FileCheck %s
+
+; CHECK: InvalidInstruction: Can't translate llvm instruction:
+; CHECK-NEXT: OpSubgroupBlockPrefetchINTEL
+; CHECK-NEXT: Ptr must point to a scalar integer type
+
+119734787 65536 393230 11 0
+2 Capability Addresses
+2 Capability Kernel
+2 Capability SubgroupBufferPrefetchINTEL
+10 Extension "SPV_INTEL_subgroup_buffer_prefetch"
+5 ExtInstImport 1 "OpenCL.std"
+3 MemoryModel 2 2
+5 EntryPoint 6 7 "test"
+3 Source 4 100000
+3 TypeFloat 3 32
+4 TypeInt 5 32 0
+2 TypeVoid 2
+4 TypePointer 4 5 3
+5 TypeFunction 6 2 4 5
+
+5 Function 2 7 0 6
+3 FunctionParameter 4 8
+3 FunctionParameter 5 9
+
+2 Label 10
+3 SubgroupBlockPrefetchINTEL 8 9
+1 Return
+
+1 FunctionEnd

test/extensions/INTEL/SPV_INTEL_subgroup_buffer_prefetch/negative_invalid_numbytes_type.spt

@@ -0,0 +1,32 @@
+; RUN: not llvm-spirv %s -to-binary -o %t.spv 2>&1 | FileCheck %s
+
+; CHECK: InvalidInstruction: Can't translate llvm instruction:
+; CHECK-NEXT: OpSubgroupBlockPrefetchINTEL
+; CHECK-NEXT: NumBytes must be a 32-bit integer scalar
+
+119734787 65536 393230 11 0
+2 Capability Addresses
+2 Capability Kernel
+2 Capability Int8
+2 Capability Int64
+2 Capability SubgroupBufferPrefetchINTEL
+10 Extension "SPV_INTEL_subgroup_buffer_prefetch"
+5 ExtInstImport 1 "OpenCL.std"
+3 MemoryModel 2 2
+5 EntryPoint 6 7 "test"
+3 Source 4 100000
+4 TypeInt 3 8 0
+4 TypeInt 5 64 0
+2 TypeVoid 2
+4 TypePointer 4 5 3
+5 TypeFunction 6 2 4 5
+
+5 Function 2 7 0 6
+3 FunctionParameter 4 8
+3 FunctionParameter 5 9
+
+2 Label 10
+3 SubgroupBlockPrefetchINTEL 8 9
+1 Return
+
+1 FunctionEnd

test/extensions/INTEL/SPV_INTEL_subgroup_buffer_prefetch/negative_invalid_storage_class.spt

@@ -0,0 +1,31 @@
+; RUN: not llvm-spirv %s -to-binary -o %t.spv 2>&1 | FileCheck %s
+
+; CHECK: InvalidInstruction: Can't translate llvm instruction:
+; CHECK-NEXT: OpSubgroupBlockPrefetchINTEL
+; CHECK-NEXT: Ptr must be in CrossWorkgroup storage class
+
+119734787 65536 393230 11 0
+2 Capability Addresses
+2 Capability Kernel
+2 Capability Int8
+2 Capability SubgroupBufferPrefetchINTEL
+10 Extension "SPV_INTEL_subgroup_buffer_prefetch"
+5 ExtInstImport 1 "OpenCL.std"
+3 MemoryModel 2 2
+5 EntryPoint 6 7 "test"
+3 Source 4 100000
+4 TypeInt 3 8 0
+4 TypeInt 5 32 0
+2 TypeVoid 2
+4 TypePointer 4 7 3
+5 TypeFunction 6 2 4 5
+
+5 Function 2 7 0 6
+3 FunctionParameter 4 8
+3 FunctionParameter 5 9
+
+2 Label 10
+3 SubgroupBlockPrefetchINTEL 8 9
+1 Return
+
+1 FunctionEnd

test/extensions/INTEL/SPV_INTEL_subgroup_buffer_prefetch/subgroup_buffer_prefetch.ll

@@ -0,0 +1,45 @@
+; RUN: llvm-spirv %s -o %t.spv --spirv-ext=+SPV_INTEL_subgroup_buffer_prefetch
+; RUN: spirv-val %t.spv
+; RUN: llvm-spirv %t.spv --to-text -o - | FileCheck %s --check-prefixes=CHECK-SPIRV,CHECK-SPIRV-TYPED-PTRS
+; RUN: llvm-spirv %t.spv -r --spirv-target-env=SPV-IR -o - | llvm-dis | FileCheck %s --check-prefix=CHECK-LLVM
+
+; RUN: llvm-spirv %s -o %t.spv --spirv-ext=+SPV_INTEL_subgroup_buffer_prefetch,+SPV_KHR_untyped_pointers
+; RUN: spirv-val %t.spv
+; RUN: llvm-spirv %t.spv --to-text -o -| FileCheck %s --check-prefixes=CHECK-SPIRV,CHECK-SPIRV-UNTYPED-PTRS
+; RUN: llvm-spirv %t.spv -r --spirv-target-env=SPV-IR -o - | llvm-dis | FileCheck %s --check-prefix=CHECK-LLVM
+
+; RUN: not llvm-spirv %s -o /dev/null 2>&1 | FileCheck %s --check-prefix=CHECK-ERROR
+
+; CHECK-ERROR: RequiresExtension: Feature requires the following SPIR-V extension:
+; CHECK-ERROR-NEXT: SPV_INTEL_subgroup_buffer_prefetch
+
+target datalayout = "e-i64:64-v16:16-v24:32-v32:32-v48:64-v96:128-v192:256-v256:256-v512:512-v1024:1024"
+target triple = "spir64-unknown-unknown"
+
+; CHECK-SPIRV-DAG: Capability SubgroupBufferPrefetchINTEL
+; CHECK-SPIRV-DAG: Extension "SPV_INTEL_subgroup_buffer_prefetch"
+; CHECK-SPIRV-UNTYPED-PTRS-DAG: Capability UntypedPointersKHR
+; CHECK-SPIRV-UNTYPED-PTRS-DAG: Extension "SPV_KHR_untyped_pointers"
+; CHECK-SPIRV-DAG: TypeInt [[#Int8Ty:]] 8 0
+; CHECK-SPIRV-DAG: TypeInt [[#Int32Ty:]] 32 0
+; CHECK-SPIRV-TYPED-PTRS-DAG: TypePointer [[#GlbPtrTy:]] 5 [[#Int8Ty]]
+; CHECK-SPIRV-UNTYPED-PTRS-DAG: TypeUntypedPointerKHR [[#GlbPtrTy:]] 5
+
+; CHECK-SPIRV: FunctionParameter [[#GlbPtrTy]] [[#Ptr:]]
+; CHECK-SPIRV: FunctionParameter [[#Int32Ty]] [[#NumBytes:]]
+; CHECK-SPIRV: SubgroupBlockPrefetchINTEL [[#Ptr]] [[#NumBytes]]
+
+; CHECK-LLVM: call spir_func void @_Z34__spirv_SubgroupBlockPrefetchINTELPU3AS1Khj(ptr addrspace(1) %{{.*}}, i32 %{{.*}})
+
+define spir_kernel void @test(ptr addrspace(1) %ptr, i32 %num_bytes) {
+entry:
+  call spir_func void @_Z34__spirv_SubgroupBlockPrefetchINTELPU3AS1Khj(ptr addrspace(1) %ptr, i32 %num_bytes)
+  ret void
+}
+
+declare spir_func void @_Z34__spirv_SubgroupBlockPrefetchINTELPU3AS1Khj(ptr addrspace(1), i32)
+
+!opencl.spir.version = !{!0}
+!spirv.Source = !{!1}
+!0 = !{i32 1, i32 0}
+!1 = !{i32 4, i32 100000}

test/extensions/INTEL/SPV_INTEL_subgroup_buffer_prefetch/subgroup_buffer_prefetch_mem_operands.ll

@@ -0,0 +1,36 @@
+; RUN: llvm-spirv %s -o %t.spv --spirv-ext=+SPV_INTEL_subgroup_buffer_prefetch
+; RUN: spirv-val %t.spv
+; RUN: llvm-spirv %t.spv --to-text -o - | FileCheck %s --check-prefix=CHECK-SPIRV
+; RUN: llvm-spirv %t.spv -r --spirv-target-env=SPV-IR -o - | llvm-dis | FileCheck %s --check-prefix=CHECK-LLVM
+
+; OpSubgroupBlockPrefetchINTEL accepts an optional Memory Operands bitmask
+; as a third operand after the required Ptr and NumBytes.
+; Test Prefetch with Nontemporal memory operand (0x4).
+
+; CHECK-SPIRV-DAG: Capability SubgroupBufferPrefetchINTEL
+; CHECK-SPIRV-DAG: Extension "SPV_INTEL_subgroup_buffer_prefetch"
+; CHECK-SPIRV-DAG: TypeInt [[#Int8Ty:]] 8 0
+; CHECK-SPIRV-DAG: TypeInt [[#Int32Ty:]] 32 0
+; CHECK-SPIRV-DAG: TypePointer [[#GlbPtrTy:]] 5 [[#Int8Ty]]
+
+; CHECK-SPIRV: FunctionParameter [[#GlbPtrTy]] [[#Ptr:]]
+; CHECK-SPIRV: FunctionParameter [[#Int32Ty]] [[#NumBytes:]]
+; CHECK-SPIRV: SubgroupBlockPrefetchINTEL [[#Ptr]] [[#NumBytes]] 4
+
+; CHECK-LLVM: call spir_func void @_Z34__spirv_SubgroupBlockPrefetchINTELPU3AS1Khjj(ptr addrspace(1) %{{.*}}, i32 %{{.*}}, i32 4)
+
+target datalayout = "e-i64:64-v16:16-v24:32-v32:32-v48:64-v96:128-v192:256-v256:256-v512:512-v1024:1024"
+target triple = "spir64-unknown-unknown"
+
+define spir_kernel void @test_nontemporal(ptr addrspace(1) %ptr, i32 %num_bytes) {
+entry:
+  call spir_func void @_Z34__spirv_SubgroupBlockPrefetchINTELPU3AS1Khjj(ptr addrspace(1) %ptr, i32 %num_bytes, i32 4)
+  ret void
+}
+
+declare spir_func void @_Z34__spirv_SubgroupBlockPrefetchINTELPU3AS1Khjj(ptr addrspace(1), i32, i32)
+
+!opencl.spir.version = !{!0}
+!spirv.Source = !{!1}
+!0 = !{i32 1, i32 0}
+!1 = !{i32 4, i32 100000}